Leo Yeh's Blog

SAS Viya (93)

教學目標

初步了解 SAS 平台中 Analytic Store (ASTORE) 的基本概念。

重點概念

首先 SAS 平台中 Analytic Store (ASTORE) 主要為分析存儲的二進位檔案,其包括分析過程中的狀態,並且被使用來自模型開發的訓練階段的結果來建立自預測分析過程的該狀態,此外分析儲存的關鍵特性主要是它能夠輕鬆地從一個主機傳輸到另一個主機,這部分主要因為它是一種通用的檔案格式,並且在模型部署中分析儲存將會恢復到預測模型的狀態,以利針對新的資料進行評分,所以非常適合用於整合開放源始碼的相關應用。

接著 PROC ASTORE 主要能夠用於描述分析儲存,對其進行管理,並且使用分析儲存對新的資料進行評分,以及產生 ASTORE 檔,當我們建立分析儲存的 ASTORE 檔之後,就能夠將它移動到我們需要的位置,並且在使用它來評估新資料。此時我們主要能夠在 SAS Studio 中執行下述兩個範例,分別針對房屋貸款和信用卡進行預測建模分析,並且執行完成之後,我們就能夠在「/tmp」暫存資料夾中找到「savelocal.astore」分析儲存的 ASTORE 檔。

範例一:房屋貸款預測建模分析

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
proc options option=(CASHOST CASPORT);
run;

cas mysess;
libname mycas cas sessref=mysess;

data mycas.hmeq;
set sampsio.hmeq;
id = _N_;
run;

proc svmachine data=mycas.hmeq;
input loan mortdue value /level=interval;
input reason job delinq ninq /level=nominal;
target bad;
id id;
savestate rstore=mycas.savehmeq;
run;

proc astore;
score data=mycas.hmeq
out=mycas.scoreout1
rstore=mycas.savehmeq;
quit;

proc astore;
download rstore=mycas.savehmeq
store="/tmp/savelocal.astore";
quit;

cas mysess terminate;

範例二:信用卡預測建模分析

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
proc options option=(CASHOST CASPORT);
run;

cas mysess;
libname mycas cas sessref=mysess;

data mycas.dmagecr;
set sampsio.dmagecr;
id=_n_;
run;

proc cas;
action svm.svmtrain /
table={name='dmagecr'},
var={'checking', 'coapp', 'depends'},
emtarget={name='telephon', options={order='formatted', leveltype='nominal'}},
kernel=2,
degree=2,
id= {'id'},
savestate={name='save', replace=true};
run;

proc cas;
aStore.describe rstore={name='save'}, epcode=TRUE;
run;
quit;

proc cas;
loadactionset "aStore";
action aStore.score /
table={name='dmagecr'},
out={name='dmagecrout'},
rstore={name='save'};
run;
quit;

proc astore;
download rstore=mycas.save store="/tmp/savelocal.astore";
run;

cas mysess terminate;

再來 PROC ASTORE 還可以在客戶端和伺服器之間移動分析儲存,並且可以提供有關分析儲存的描述性資訊,主要可以分為四種操作方式,分別為:

  1. 評分:主要針對模型進行評分。
  2. 描述:主要指定分析儲存的名稱,並且產生基本評分程式碼。
  3. 下載:主要從 CAS Session 中檢索指定的分析儲存,並將其儲存在本地檔案系統中。
  4. 上傳:主要將指定的分析儲存從本地檔案系統移動至 CAS 中的資料表中。

最後 ASTORE 檔主要要是 SAVESTATE 的輸出,至於所謂狀態主要是與下一個任務相關的所有資訊,其主要包括公開資訊和私有資訊,分別為:

  1. 公開資訊:主要是所有分析引擎共有的資訊,像是輸入變數列表、輸出變數列表、格式、…等資訊。
  2. 私有資訊:主要是特定於該特定分析的資訊,像是隨機森林主要有樹木的數量、樹木本身、分數、…等資訊。

相關資源

⬅️ Go back